Determine if user is member of team or department

Determining if a user is a member of a team or department in SalesLogix is a useful thing. You often want to only allow members of a particular team to access some function or maybe have a screen appear differently depending on which department the user is in.

Here’s a generic & reusable function that I use:

' sGroupType = "T" for team, and "D" for department
Function IsMember(ByVal sUser, ByVal sGroup, ByVal sGroupType)
Dim objRS

    If sGroupType = "T" Then sGroupType = "G"
    Set objRS = CreateObject("ADODB.Recordset")
    With objRS
         Set .ActiveConnection = Application.GetNewConnection
         .Open "select accessid from secrights where seccodeid = " & _
                   "(select seccodeid from seccode where (seccodedesc = '" & sGroup & "') " & _
                   "and (seccodetype = '" & sGroupType & "')) and (accessid = '" & sUser & "')"

         If Not (.EOF Or .BOF) Then
            IsMember = (.Fields(0).Value & "" = sUser)
         Else
             IsMember = False
         End If
         .Close
    End With
    Set objRS = Nothing
End Function

Put that in a VBScript and include it when ever you need it. To use it you just pass the userid, the name of department or team, and the type (either “T” for Team, or a “D” for Department.). The function returns a boolean value indicating if the user is a memeber of the team or department.

ie:

If IsMember("UFFED0000027", "Development", "D") Then
    MsgBox "Is a member"
End If

-or-

If IsMember("UFFED0000027", "Midwest", "T") Then
    MsgBox "Is a member"
End If

If you wanted to, you could get rid of the sGroupType param and modify the query to not include the SECCODETYPE in the where clause of the query. By doing so you would be checking both Teams and Departments for the match. But, if there was a department named Development and a Team named Development (I don’t know if you can even have both named the same) then you’d get a true value back either way. I like to leave it where I am explicity checking either Teams or Departments, not both.